/********************************************************************************************************************************************
// 
// Macro voor gelijkrichter bruggen met DT80CA en DT80CB behuizing
//
// Toegevoegd door Theo Van Hoof ikke[at]theovanhoof.be
//
// volgende 2 regels toevoegen aan 3dusrpac.dat
DT80C:0:1:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:DIODE_DT80CA(: Diotec gelijkrichterbrug + ~ ~ -:
DT80CB:0:1:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:0:DIODE_DT80CB(: Diotec gelijkrichterbrug ~ + ~ -:
// 
********************************************************************************************************************************************/ 
#macro DIODE_DT80C_GRND(value, T)
union{ 
        cylinder { // de aansluitdraden
           <7.55, 0, 0>
           <7.55, -min(7.7,(pin_length+pcb_height)), 0>, 0.4
           texture{col_silver}
        }

        cylinder {
           <2.55, 0, 0>
           <2.55, -min(7.7,(pin_length+pcb_height)), 0>, 0.4
           texture{col_silver}
        } 
        cylinder {
           <-2.55, 0, 0>
           <-2.55, -min(7.7,(pin_length+pcb_height)), 0>, 0.4
           texture{col_silver}
        }

        cylinder {
           <-7.55, 0, 0>
           <-7.55, -min(7.7,(pin_length+pcb_height)), 0>, 0.4
           texture{col_silver}
        }
        difference{ 
                box{//de package  
                        <-9.5, 0, -1.75>
                        <9.5, 10, 1.75>
                        pigment{Gray10}
                        normal { bumps 0.2 scale 0.15 }   // { bumps 0.2 scale 0.3 }
                        finish { ambient 0.1 diffuse 0.6 brilliance 1.0 }
                }
                // hoekje van de package verwijderen aan de - zijde
                box{
                        <6.5, 12, -4.75>
                        <10.5, 8.5, 2.75>
                        rotate<0, 0, -45>
                        translate<-3.9, 9, 0>
                        //pigment{Gray90} // toegevoegd om te testen
                }
 
        } 
        // + ~ ~ -
        #if(T = 0)
                text {
                        ttf besch_font "+", 0.2, 0  
                        pigment{Gray60}                        
                        translate<-7.58, 1.3, -1.78>
                }
     
                text {
                        ttf besch_font "~", 0.2, 0  
                        pigment{Gray60}                        
                        translate<-2.58, 1.3, -1.78>
                }
        #end 
        // ~ + ~ -
        #if(T = 1)
                text {
                        ttf besch_font "~", 0.2, 0  
                        pigment{Gray60}                        
                        translate<-7.58, 1.3, -1.78>
                }
     
                text {
                        ttf besch_font "+", 0.2, 0  
                        pigment{Gray60}                        
                        translate<-2.58, 1.3, -1.78>
                }
        #end
        text {
                ttf besch_font "~", 0.2, 0  
                pigment{Gray60}                        
                translate<2.52, 1.3, -1.78>
        }
        text {
                ttf besch_font "-", 0.2, 0  
                pigment{Gray60}                        
                translate<7.52, 1.3, -1.78>
        } 
        // waarde op brug zetten
        text {
                ttf besch_font value, 0.2, 0  
                pigment{Gray60}
                scale 2                        
                translate<-5, 4, -1.78>
        } 
        
        

}
#end

#macro DIODE_DT80CA(value)
        #object{DIODE_DT80C_GRND(value, 0)}
#end
#macro DIODE_DT80CB(value)
        #object{DIODE_DT80C_GRND(value, 1)}
#end